Cylinder radial segment primitive object for Papervision3D

May 19th, 2008 at 08:59am daniel.sedlacek

If you're new here, you may want to subscribe to my RSS feed. If you like my site, consider linking back. I prefer text "Free Flash Tutorials" to http://blog.franto.com
Thanks for visiting my site! If you need anything just contacting through Contact page or Gtalk widget

For my latest project I needed to display 3D cylinder slices - Papervision was an obvious choice. Unfortunately the primitive cylinder class does not work this way, the cylinder is built as a square mesh with no option for segment slices. So I had to help myself, I started to play with the almost undocumented PV3D primitives, step by step modifying the original cylinder class and after couple hours I dig out what is what and derived my RadialSegment class. It follows the original concept with one material for whole object, supports UV mapping and inherit all other properties. Here it is, use it as you wish.

papervision3d cylinder radial segment

Code and live example in full article

Here is live example and source code follows:

PLAIN TEXT
Actionscript:
  1. package {
  2. import org.papervision3d.core.geom.*;
  3. import org.papervision3d.core.geom.renderables.Triangle3D;
  4. import org.papervision3d.core.geom.renderables.Vertex3D;
  5. import org.papervision3d.core.math.NumberUV;
  6. import org.papervision3d.core.proto.*;
  7.  
  8. /**
  9. * The RadialSegment class lets you create and display cylinders radial segments.
  10. *
  12. * The RadialSegment is divided in horizontal mesh segments and vertical ragial segments.
  13. *    * Derivated from original Cylinder class by Daniel Sedlacek (sedlacek.daniel@gmail.com).
  14. *    * Please follow the original Papervision3D license.
  15. */
  16. public class RadialSegment extends TriangleMesh3D {
  17. /**
  18. * Number of segments horizontally. Defaults to 8.
  19. */
  20. public var segmentsW : Number;    /**
  21. * Number of segments vertically. Defaults to 6.
  22. */
  23. public var segmentsH : Number;
  24.  
  25. /**
  26. * Default radius of Segment3D if not defined.
  27. */
  28. static public var DEFAULT_RADIUS : Number = 100;
  29.  
  30. /**
  31. * Default height if not defined.
  32. */
  33. static public var DEFAULT_HEIGHT : Number = 50;
  34.  
  35. /**
  36. * Default value of gridX if not defined.
  37. */
  38. static public var DEFAULT_SEGMENTSW : Number = 8;
  39.  
  40. /**
  41. * Default value of gridY if not defined.
  42. */
  43. static public var DEFAULT_SEGMENTSH : Number = 2;
  44.  
  45. /**
  46. * Minimum value of gridX.
  47. */
  48. static public var MIN_SEGMENTSW : Number = 3;
  49.  
  50. /**
  51. * Minimum value of gridY.
  52. */
  53. static public var MIN_SEGMENTSH : Number = 1;
  54.  
  55. /**
  56. * Create a new Cylinder object.
  57. *
  59. * @param    material    [optional] - A MaterialObject3D object that contains the material properties of the object.
  60. *     * @param    angle      [optional] - Desired segment angle <0,1>.
  61. *     * @param    radius    [optional] - Desired radius.
  62. *     * @param    segmentsW   [optional] - Number of segments horizontally. Defaults to 8.
  63. *     * @param    segmentsH   [optional] - Number of segments vertically. Defaults to 6.
  64. *     * @param    topRadius   [optional] - An optional parameter for con- or diverging cylinders
  65. *     * @param    initObject  [optional] - An object that contains user defined properties with which to populate the newly created GeometryObject3D.
  66. *     * It includes x, y, z, rotationX, rotationY, rotationZ, scaleX, scaleY scaleZ and a user defined extra object.
  67. *     * If extra is not an object, it is ignored. All properties of the extra field are copied into the new instance. The properties specified with extra are publicly available.
  68. */
  69. public function RadialSegment( material : MaterialObject3D = null, angle : Number = 0.25, radius : Number = 100, height : Number = 100, segmentsW : int = 8, segmentsH : int = 2, topRadius : Number = -1, initObject : Object = null ) {
  70. super(material, new Array(), new Array(), null, initObject);            this.segmentsW = Math.max(MIN_SEGMENTSW, segmentsW || DEFAULT_SEGMENTSW);
  71. // Defaults to 8
  72. this.segmentsH = Math.max(MIN_SEGMENTSH, segmentsH || DEFAULT_SEGMENTSH);
  73. // Defaults to 6
  74. if (radius == 0) radius = DEFAULT_RADIUS;
  75. // Defaults to 100
  76. if (height == 0) height = DEFAULT_HEIGHT;
  77. // Defaults to 100
  78. if (topRadius == -1) topRadius = radius;
  79. // segment
  80. angle = angle> 1 ? 1 : angle <0 ? 0 : angle;
  81.  
  82. buildSegment(angle, radius, height, topRadius);
  83. }
  84.  
  85. private function buildSegment( fAngle : Number, fRadius : Number, fHeight : Number,  fTopRadius : Number ) : void {
  86. var matInstance : MaterialObject3D = material;
  87.  
  88. var i : Number, j : Number;
  89.  
  90. var iHor : Number = this.segmentsW + 1;
  91. var iVer : Number = this.segmentsH;
  92. var aVertice : Array = this.geometry.vertices;
  93. var aFace : Array = this.geometry.faces;
  94. var aVtc : Array = new Array();
  95.  
  96. for (j = 0;j <(iVer + 1);j++) {
  97. // vertical
  98. var fZ : Number = fHeight * (j / (iVer + 0)) - fHeight / 2;
  99. //-fRadius*Math.cos(fRad1*Math.PI);
  100. var fRds : Number = fTopRadius + (fRadius - fTopRadius) * (1 - j / (iVer));
  101. //*Math.sin(fRad1*Math.PI);
  102. var aRow : Array = new Array();
  103. var oVtx : Vertex3D;
  104.  
  105. for (i = 0;i <iHor;i++) {
  106. // horizontal
  107. var fRad2 : Number = Number(2 * i / (iHor - 1));
  108. var fX : Number = fRds * Math.sin(fRad2 * Math.PI * fAngle);
  109. var fY : Number = fRds * Math.cos(fRad2 * Math.PI * fAngle);
  110. oVtx = new Vertex3D(fY, fZ, fX);
  111.  
  112. aVertice.push(oVtx);
  113. aRow.push(oVtx);
  114. }
  115.  
  116. // special middle vertex
  117. oVtx = new Vertex3D(0, fZ, 0);
  118. aVertice.push(oVtx);
  119. aRow.push(oVtx);
  120.  
  121. aVtc.push(aRow);
  122. }
  123. var iVerNum : int = aVtc.length;
  124.  
  125. var aP4uv : NumberUV, aP1uv : NumberUV, aP2uv : NumberUV, aP3uv : NumberUV;
  126. var aP1 : Vertex3D, aP2 : Vertex3D, aP3 : Vertex3D, aP4 : Vertex3D;
  127.  
  128. for (j = 0;j <iVerNum;j++) {
  129. var iHorNum : int = aVtc[j].length;
  130. for (i = 0;i <iHorNum;i++) {
  131. if (j> 0 && i>= 0) {
  132. // select vertices
  133. var bEnd : Boolean = i == (iHorNum - 0);
  134. aP1 = aVtc[j][bEnd ? 0 : i];
  135. aP2 = aVtc[j][(i == 0 ? iHorNum : i) - 1];
  136. aP3 = aVtc[j - 1][(i == 0 ? iHorNum : i) - 1];
  137. aP4 = aVtc[j - 1][bEnd ? 0 : i];
  138. // uv
  139. var fJ0 : Number = j / iVerNum;
  140. var fJ1 : Number = (j - 1) / iVerNum;
  141. var fI0 : Number = (i + 1) / iHorNum;
  142. var fI1 : Number = i / iHorNum;
  143. aP4uv = new NumberUV(fI0, fJ1);
  144. aP1uv = new NumberUV(fI0, fJ0);
  145. aP2uv = new NumberUV(fI1, fJ0);
  146. aP3uv = new NumberUV(fI1, fJ1);
  147.  
  148. aFace.push(new Triangle3D(this, [aP1,aP2,aP3], matInstance, [aP1uv,aP2uv,aP3uv]));
  149. aFace.push(new Triangle3D(this, [aP1,aP3,aP4], matInstance, [aP1uv,aP3uv,aP4uv]));
  150. }
  151. }
  152. if (j == 0 || j == (iVerNum - 1)) {
  153. for (i = 0;i <(iHorNum - 2);i++) {
  154. // uv
  155.  
  156. aP1 = aVtc[j][iHorNum - 1];
  157. aP2 = aVtc[j][i];
  158. aP3 = aVtc[j][i + 1];
  159.  
  160. var bTop : Boolean = j == 0;
  161. aP1uv = new NumberUV((bTop ? 1 : 0) + (bTop ? -1 : 1) * (aP1.x / fRadius / 2 + .5), aP1.z / fRadius / 2 + .5);
  162. aP2uv = new NumberUV((bTop ? 1 : 0) + (bTop ? -1 : 1) * (aP2.x / fRadius / 2 + .5), aP2.z / fRadius / 2 + .5);
  163. aP3uv = new NumberUV((bTop ? 1 : 0) + (bTop ? -1 : 1) * (aP3.x / fRadius / 2 + .5), aP3.z / fRadius / 2 + .5);
  164.  
  165. // face
  166. if (j == 0) aFace.push(new Triangle3D(this, [aP1,aP3,aP2], matInstance, [aP1uv,aP3uv,aP2uv]));
  167. else        aFace.push(new Triangle3D(this, [aP1,aP2,aP3], matInstance, [aP1uv,aP2uv,aP3uv]));
  168. }
  169. }
  170. }
  171. this.geometry.ready = true;
  172. }
  173. }
  174. }

, , , ,
AddThis Feed Button

Entry Filed under: Library, Papervision, 3D, ActionScript, Flash


Do you want to receive fresh news from my site?
Subscribe to my RSS

»Related posts:



3 Responses to “Cylinder radial segment primitive object for Papervision3D”

  1. 1
    Cylinder radial segment primitive object for Papervision3D Says:
    May 19th, 2008 at 9:12 am

    […] The Hen wrote an interesting post today onHere’s a quick excerptFor my latest project I needed to display 3D cylinder slices - Papervisionwas an obvious choice. Unfortunately the primitive cylinder class does not work this way, the cylinder is built as a square mesh with no option for segment slices … […]

  2. 2
    flash your Says:
    May 19th, 2008 at 10:19 am

    […] project I needed to display 3D cylinder slices - Papervisionwas an obvious choice. Unfortunately thttp://www.franto.com/blog2/cylinder-radial-segment-primitive-object-for-papervision3dWhat’s the best flash memory flavor for your design? Electronic Engineering Times AsiaThe embedded […]

  3. 3
    Pages tagged "the primitives" Says:
    May 21st, 2008 at 4:15 am

    […] the primitivesOwn a Wordpress blog? Make monetization easier with the WP Affiliate Pro plugin. Cylinder radial segment primitive object for Paper… saved by 4 others     yourmyslave bookmarked on 05/20/08 | […]

Leave a Reply